@echo off
color 0D
MODE con: COLS=71 LINES=25
rem schtasks /create /tn "beifenwenjian.bat" /tr E:\文档备份\beifenwenjian.bat /sc daily /st 16:59:00 /RU SYSTEM
title 办公文件自动备份脚本(任务计划)--作者：小雨
set sou_dir="D:\我的文档"
set obj_dir="E:\文件备份"
set expireddays=60
if exist %obj_dir%\%date:~0,4%-%date:~5,2%-%date:~8,2% echo %date:~0,10%数据已经备份过-退出备份程序 >> %obj_dir%\backup.log  && exit/b
md %obj_dir%\%date:~0,4%-%date:~5,2%-%date:~8,2%
xcopy /e /c /h /y %sou_dir% %obj_dir%\%date:~0,4%-%date:~5,2%-%date:~8,2%
echo %date% %time% %date:~0,4%-%date:~5,2%-%date:~8,2% 备份完成 >> %obj_dir%\backup.log

rem 删除指定天数之前的备份
@echo off & setlocal enabledelayedexpansion
call :GetDate y m d
call :DateToDays %y% %m% %d% days1
@for /f "tokens=1-3 delims=-" %%a in ('dir /b/ad') do (
  call :DateToDays %%a %%b %%c days2
  set/a days=days1-days2
  if !days! GEQ %expireddays% rd /q /s "%%~fa-%%b-%%c"
)
endlocal
exit /b

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF
:GetDate yyyy mm dd
setlocal ENABLEEXTENSIONS
set "first="
for /f "tokens=1-3 delims=.-/ " %%a in ('date/t') do (
if not defined first set first=1&set yy=%%a&set mm=%%b&set dd=%%c)
endlocal&set %1=%yy%&set %2=%mm%&set %3=%dd%&goto :EOF